SUMIF函数14种经典用法，速收！

赵乾舟

SUMIF函数是使用频率很高的函数，通常用于对区域中符合指定的单个条件的值求和。
她只有3个参数，看起来像清纯的少女。
=SUMIF(条件区域,指定的条件,需要求和的区域)
如果省略求和区域，会将条件区域作为求和区域。
今天咱们就一起揭开SUMIF函数清纯的面纱，领略一下她的盖世武功。

1、返回如花的销售额。

1. =SUMIF(B:B,"如花",C:C)

复制代码

2、返回除了如花之外的销售额。

1. =SUMIF(B:B,"<>如花",C:C)

复制代码

3、返回大于900的销售额

1. =SUMIF(C:C,">900")

复制代码

4、返回低于平均值的销售总额

1. =SUMIF(C:C,"<"&AVERAGE(C:C))

复制代码

注意，当使用其他公式作为求和条件时，如果在求和条件的公式前使用大于、小于、不等于这些比较运算符，运算符前后要使用半角引号，同时要使用连接符&，将比较运算符与公式连接起来。


5、返回等于单元格E1中姓名的销售额

1. =SUMIF(B:B,E1,C:C)

复制代码

6、返回B列不为空的销售额

1. =SUMIF(B:B,"*",C:C)

复制代码

7、返回姓名为三个字的销售额

1. =SUMIF(B:B,"???",C:C)

复制代码

8、返回在姓名中任何位置包含“花”销售额

1. =SUMIF(B:B,"*花*",C:C)

复制代码

9、返回姓名以“花”开头的销售额

1. =SUMIF(B:B,"花*",C:C)

复制代码

10、返回当前日期的销售额

1. =SUMIF(A:A,TODAY(),C:C)

复制代码

11、返回忽略错误值的销售额

1. =SUMIF(C:C,"<9e307")

复制代码

求和参数省略，以条件区域C:C作为求和区域，求和条件是<9e307,相当于对所有数值求和。


12、返回如花和秋花的销售总额

1. =SUM(SUMIF(B:B,{"如花","秋花"},C:C))

复制代码

13、返回每个人最后一次考核分数的平均分

1. =SUMIF(B3:F10,"",B2:F9)/5

复制代码

条件和求和区域错行引用，求和条件为""，需要好好理解


14、返回如花的销售总额

1. =SUMIF(B:E,"如花",C:F)

复制代码

条件和求和区域错列引用。如果B:E列等于求和条件“如花”，则对C:F求和。


SUMIF
转载请注明来源"ExcelHome"并保留原文链接。
固定链接：http://www.excelhome.net/lesson/article/excel/1744.html