请选择 进入手机版 | 继续访问电脑版

 找回密码
 立即注册
搜索
热搜: Excel discuz
查看: 3836|回复: 0

SUMIF函数14种经典用法,速收!

[复制链接]

482

主题

7万

元宝

75万

积分

管理员

Rank: 9Rank: 9Rank: 9

积分
750844
发表于 2020-3-24 20:10:12 | 显示全部楼层 |阅读模式
SUMIF函数是使用频率很高的函数,通常用于对区域中符合指定的单个条件的值求和。
她只有3个参数,看起来像清纯的少女。
=SUMIF(条件区域,指定的条件,需要求和的区域)
如果省略求和区域,会将条件区域作为求和区域。
今天咱们就一起揭开SUMIF函数清纯的面纱,领略一下她的盖世武功。

1、返回如花的销售额。
  1. =SUMIF(B:B,"如花",C:C)
复制代码


3-16021H03431510.jpg

2、返回除了如花之外的销售额。
  1. =SUMIF(B:B,"<>如花",C:C)
复制代码


3-16021H0344HB.jpg

3、返回大于900的销售额
  1. =SUMIF(C:C,">900")
复制代码


3-16021H03502S0.jpg

4、返回低于平均值的销售总额
  1. =SUMIF(C:C,"<"&AVERAGE(C:C))
复制代码


注意,当使用其他公式作为求和条件时,如果在求和条件的公式前使用大于、小于、不等于这些比较运算符,运算符前后要使用半角引号,同时要使用连接符&,将比较运算符与公式连接起来。
3-16021H03515942.jpg

5、返回等于单元格E1中姓名的销售额
  1. =SUMIF(B:B,E1,C:C)
复制代码


3-16021H0352bT.jpg

6、返回B列不为空的销售额
  1. =SUMIF(B:B,"*",C:C)
复制代码


3-16021H03552640.jpg

7、返回姓名为三个字的销售额
  1. =SUMIF(B:B,"???",C:C)
复制代码


3-16021H03605558.jpg

8、返回在姓名中任何位置包含“花”销售额
  1. =SUMIF(B:B,"*花*",C:C)
复制代码


3-16021H0361c46.jpg

9、返回姓名以“花”开头的销售额
  1. =SUMIF(B:B,"花*",C:C)
复制代码


3-16021H03631947.jpg

10、返回当前日期的销售额
  1. =SUMIF(A:A,TODAY(),C:C)
复制代码


3-16021H0364bV.jpg

11、返回忽略错误值的销售额
  1. =SUMIF(C:C,"<9e307")
复制代码


求和参数省略,以条件区域C:C作为求和区域,求和条件是<9e307,相当于对所有数值求和。
3-16021H03F4342.jpg

12、返回如花和秋花的销售总额
  1. =SUM(SUMIF(B:B,{"如花","秋花"},C:C))
复制代码


3-16021H03H1517.jpg

13、返回每个人最后一次考核分数的平均分
  1. =SUMIF(B3:F10,"",B2:F9)/5
复制代码


条件和求和区域错行引用,求和条件为"",需要好好理解
3-16021H03IC38.png

14、返回如花的销售总额
  1. =SUMIF(B:E,"如花",C:F)
复制代码


条件和求和区域错列引用。如果B:E列等于求和条件“如花”,则对C:F求和。
3-16021H03K53U.jpg

SUMIF
转载请注明来源"ExcelHome"并保留原文链接。
固定链接:http://www.excelhome.net/lesson/article/excel/1744.html
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

Archiver|手机版|小黑屋|五花八门论坛 ( 豫ICP备15031300号-3 )

GMT+8, 2024-3-29 15:37 , Processed in 0.098263 second(s), 21 queries .

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表